Perl から YouTube の新API を使って動画をアップロードする

昨日の夕方頃、YouTube API のドキュメントを見たら、急に内容が追加されていてびっくらこいたわけですが、 YouTube の API に新しく、動画をアップロードする機能やプレイヤーをJavaScriptから制御できる機能が追加されました。というわけで、早速 Perl を使ってローカルにある動画をYouTubeにアップロードするスクリプトを書いてみました。いろいろと癖があるので、適当に解説をします。

今回試したのは「Direct Uploading」という方法で、ローカルにあるスクリプトから直接動画ファイルを読み込んでポストするものです。他にもウェブフォームからユーザーにファイルを選んでもらってアップロードするやりかたもあるようです。この新API、とても充実しています（その代わりなのか昨日はやたらGDataのフィードが重たかったよ！）。

アップロードする流れは以下の順番になります。

Developer Key を取得
YouTube アカウントでの認証
authentication_token の取得
アップロードするビデオ情報の設定
リクエストの作成
アップロード
結果の得取

YouTube にある動画を検索して結果を取得するだけなら、GDataのフィードを読めばいいので、関係ないのですが、今回の場合は Developer Key が必要になってきます。以下のページから登録ができます。

http://code.google.com/apis/youtube/dashboard/developerSignup

次にYouTubeアカウントの認証について説明します。動画をアップロードするとなると、その人のYouTubeのアカウント名義でアップロードするわけであり、そのアカウント情報を用いて認証をしなければなりません。いつもYouTubeで利用しているユーザー名とパスワードを認証URLにPOSTで渡して、authentication_token とやらを取得します。この authentication_token がアップロードをするリクエストに必要になってきます。認証だけならリクエストURLに対してPOSTメソッドを発行するだけです。最後にアップロードするサンプルスクリプトを掲載しますが、そのサンプルから認証をするサブルーチンを紹介すると以下のようになります。HTTP::Request::Common を使ってPOSTのリクエストを生成しています。 Emailパラメータにはユーザーアカウントを入れます。Emailとありますが、YouTubeに登録しているメールアドレスではありません。アカウント名です。これが、最初にはまったポイントです。source パラメータはなんか適当に入れてればよさげ。

 
use LWP::UserAgent;
use HTTP::Request::Common;

my $ua = LWP::UserAgent->new;

sub auth {
    my $request = POST(
        "https://www.google.com/youtube/accounts/ClientLogin",
        Content_Type => 'application/x-www-form-urlencoded',
        Content      => [
            Email   => $username,
            Passwd  => $password,
            service => "youtube",
            source  => "uploads",
        ],
    );
    my $response = $ua->request($request);
    die $response->status_line unless ( $response->is_success );
    $response->content =~ /Auth=(.*?)\n/;
    return $1;
}

返ってきた文字列からAuth=xxxxxxxxxxxxxxxxxxという部分を抜き出せばそれがauthentication_tokenとなります。

次にアップロードするビデオの設定をします。基本的にGDataということで、ビデオの情報をAtomのentry形式で記述します。Atomとはいえ、その記述形式がYahoo!のMedia RSSを使っているので、モジュールは使わないで、テキストで書いてみました。もっとスマートなやり方があると思いますが、とりあえずわかりやすいので。これもサブルーチンにしています。

 sub video_detail {
    my $param = shift;
    foreach my $key ( keys %$param ){
        utf8::encode($param->{$key}) if utf8::is_utf8($param->{$key});
    }
    my $title = $param->{title} || die "title is required";
    my $description = $param->{description} || die "description is required";
    my $category = $param->{category} || "People";
    my $keywords = $param->{keywords} || die "keywords is required";

my $video_detail = << "XML";
<?xml version="1.0"?>
<entry xmlns="http://www.w3.org/2005/Atom"
 xmlns:media="http://search.yahoo.com/mrss/"
 xmlns:yt="">http://gdata.youtube.com/schemas/2007">
    <media:group>
    <media:title type="plain">$title</media:title>
    <media:description type="plain">$description</media:description>
    <media:category scheme="$category">http://gdata.youtube.com/schemas/2007/categories.cat">$category
    <media:keywords>$keywords</media:keywords>
  </media:group>
</entry>
XML
   return $video_detail;
}

それぞれのパラメータが無いとdieしてますが、これらが空だとアップロードした時にAPIから怒られちゃいますので、しっかり設定しましょう。これも軽くはまりました。

この様にビデオの情報とそのビデオ自体のファイルを手元に用意したら、POSTのリクエスト作成します。以下のURLがPOSTする先のURLです。

 http://uploads.gdata.youtube.com/feeds/api/users//uploads

リクエストのヘッダーに含める要素が結構あって、まず、Content-Type は multipart/related にしなければいけません。次に認証がらみで、上記の authentication_token と developer key を

 Authorization: GoogleLogin token=<authentication_token>
X-GData-Key: key=<developer_key>

という形式で含めます。ここが一番はまったところで、ドキュメントによると、Authorization のところが

 Authorization: AuthSub token=<authentication_token>

になっていて、最初はこちらで試していたのですが、はねられました。このAuthSubというのは今回の「Direct Uploading」では使えなくて、ウェブフォームから外部ユーザーによってアップロードする場合などに使うようです。

ヘッダーの次は、リクエストの中にいれるコンテンツを入れます。用意しておいたビデオ情報の Atom 及び実際の動画ファイルであるバイナリ形式のデータです。それぞれ、Content-Typeを「application/atom+xml」、動画の場合はそれにあった、例えば「video/mpeg」などにします。 upload サブルーチンのリクエスト生成までのコードはこんな感じです。

 sub upload {
    my $token = shift;
    my $url =
      "http://uploads.gdata.youtube.com/feeds/api/users/$username/uploads";
    my $request = HTTP::Request->new( POST => $url );

    $request->header(
        "Authorization" => "GoogleLogin auth=$token",
        "X-GData-Key"   => "key=$developer_key",
        Slug            => $filename,
        Content_Type    => 'multipart/related',
    );
    $request->add_part(
        HTTP::Message->new(
            [ Content_type => 'application/atom+xml' ],
            $video_detail
        )
    );
    $request->add_part(
        HTTP::Message->new( [ Content_type => $content_type ], $data ) );

それで、いよいよリクエスト発行します。うまくいかなければエラーが返ってきますし、うまくいけばアップロードした動画のYouTubeでの情報がGData形式で返却されます。その部分が upload サブルーチンの残りの部分になります。取得したGDataはそのままprintしていますが、利用する場合はパースなどをしましょう。

     my $response = $ua->request($request);
    die $response->status_line unless ( $response->is_success );
    print $response->content;
}

以上でアップロードは完了です。YouTubeにログインしMyAccountのMyVideo（http://www.youtube.com/my_videos）にアクセスしたら変換中のさきほどあげた動画があれば成功というわけです。

youtube

アカウントのことも含め情報を全てコードに記述しているので、モジュール化したいところではありますが、とりあえずうまくいったということでめでたしめでたし。これを使っていろんなことができそうですね！以下、アップロードするサンプルの全コードになります。

 #!/usr/bin/perl

use strict;
use warnings;
use LWP::UserAgent;
use HTTP::Request;
use HTTP::Request::Common;
use IO::All;
use utf8;

# account settings
my $username = "your_account";
my $password = "your_password";
my $developer_key = "your_developer_key";

# video settings
my $filename = "movie01.mpg";
my $content_type = "video/mpeg";
my $video_detail = video_detail(
    {
        title       => "test",
        description => "description",
        keywords    => "tag1,tag2",
    }
);

my $ua    = LWP::UserAgent->new( keep_alive => 1 );
my $data  = io($filename)->binary->all;
my $token = auth();
upload($token);

sub upload {
    my $token = shift;
    my $url =
      "http://uploads.gdata.youtube.com/feeds/api/users/$username/uploads";
    my $request = HTTP::Request->new( POST => $url );

    $request->header(
        "Authorization" => "GoogleLogin auth=$token",
        "X-GData-Key"   => "key=$developer_key",
        Slug            => $filename,
        Content_Type    => 'multipart/related',
    );
    $request->add_part(
        HTTP::Message->new(
            [ Content_type => 'application/atom+xml' ],
            $video_detail
        )
    );
    $request->add_part(
        HTTP::Message->new( [ Content_type => $content_type ], $data ) );

    my $response = $ua->request($request);
    die $response->status_line unless ( $response->is_success );
    print $response->content;
}

sub auth {
    my $request = POST(
        "https://www.google.com/youtube/accounts/ClientLogin",
        Content_Type => 'application/x-www-form-urlencoded',
        Content      => [
            Email   => $username,
            Passwd  => $password,
            service => "youtube",
            source  => "uploads",
        ],
    );
    my $response = $ua->request($request);
    die $response->status_line unless ( $response->is_success );
    $response->content =~ /Auth=(.*?)\n/;
    return $1;
}

sub video_detail {
    my $param = shift;
    foreach my $key ( keys %$param ){
    utf8::encode($param->{$key}) if utf8::is_utf8($param->{$key});
    }
    my $title = $param->{title} || die "title is required";
    my $description = $param->{description} || die "description is required";
    my $category = $param->{category} || "People";
    my $keywords = $param->{keywords} || die "keywords is required";

my $video_detail = << "XML";
<?xml version="1.0"?>
<entry xmlns="http://www.w3.org/2005/Atom"
 xmlns:media="http://search.yahoo.com/mrss/"
 xmlns:yt="">http://gdata.youtube.com/schemas/2007">
    <media:group>
    <media:title type="plain">$title</media:title>
    <media:description type="plain">$description</media:description>
    <media:category scheme="$category">http://gdata.youtube.com/schemas/2007/categories.cat">$category
    <media:keywords>$keywords</media:keywords>
  </media:group>
</entry>
XML
   return $video_detail;
}